C N. R. BADNELL                                                 19/02/21
C
      PROGRAM TWIG9J
C
C-----------------------------------------------------------------------
C TEST
C EVALUATION OF WIGNER 9-J SYMBOL BY SUMMATION OF 6-J 3-PRODUCT (WIG6JR)
C
C EXAMPLES:
C
C JOHANSSON & FORSSEN (SIAM J.SCI.COMPUT. 38, A376 (2016))
C  17   19   14    25   16   17    16   21   19
C 200  160  100   100  200  140   120  100  200
C 400  400  400   400  400  400   400  400  400
C
C-----------------------------------------------------------------------
C
      IMPLICIT REAL*8 (A-H,O-Z)
C
      PARAMETER (IWRITE=0)              !=0 TO SCREEN, >0 TO WIG9J.out
C
C
      IF(IWRITE.GT.0)OPEN(IWRITE,FILE='WIG9J.out')    !STATUS='UNKNOWN'
C
C ASK USER TO ENTER ALL *NINE* PREDEFINED ARGUMENTS a-i (rowwise)
C
      WRITE(*,*)
     X"DETERMINES WIGNER 9-J SYMBOL W9J FOR GIVEN a-i (rowwise)"
      WRITE(*,*)
C
   1  WRITE(*,*)"ENTER THE 9 INTEGERS (a-i) AT *TWICE* "
     X         ,"ACTUAL VALUE (any.lt.0 exits):"
C
      READ(*,*)IA,IB,IC,ID,IE,IF,IG,IH,II
C
      IF(
     X   IA.LT.0.OR.IB.LT.0.OR.IC.LT.0 .OR.
     X   ID.LT.0.OR.IE.LT.0.OR.IF.LT.0 .OR.
     X   IG.LT.0.OR.IH.LT.0.OR.II.LT.0
     X                                )THEN
        WRITE(*,*)'*** EXITING AS ARGUMENTS ARE NOT ALL .GE. ZERO'
        IF(IWRITE.GT.0)WRITE(*,*)'*** W9J OUTPUT IN WIG9J.out'
        STOP
      ENDIF
c
ct       call cpu_time(timei)
C
      A1=IA
      A1=A1/2
      A2=IB
      A2=A2/2
      A3=IC
      A3=A3/2
      B1=ID
      B1=B1/2
      B2=IE
      B2=B2/2
      B3=IF
      B3=B3/2
      C1=IG
      C1=C1/2
      C2=IH
      C2=C2/2
      C3=II
      C3=C3/2
C
ct      do i=1,10000
      CALL WIG9J(W9J,A1,A2,A3,B1,B2,B3,C1,C2,C3,KMIN,KMAX,IH0)
ct      enddo
c
ct       call cpu_time(timef)
ct       times=timef-timei
ct       write(*,"(' recursion time=',1pe9.1,' msecs')")times*1000
C
      IF(KMIN.LT.0)THEN
        IF(KMIN.EQ.-3)THEN                            !SHOULD NOT HAPPEN
          WRITE(*,*)'*** DIMENSION FAILURE, INCREASE NDIMW TO ',KMAX
        ELSE
          WRITE(*,*)'*** SELECTION RULE FAILURE, ALL 9-J EQUAL ZERO!'
          IF(KMIN.EQ.-1)WRITE(*,*)'*** non-integer triangle sum'
          IF(KMIN.EQ.-2)WRITE(*,*)'*** triangle rule failure'
        ENDIF
        GO TO 1
      ENDIF
C
      IF(IWRITE.GT.0)WRITE(*,"('W9J=',1P2D25.16)")W9J
C
      IF(IWRITE.GE.0)
     X   WRITE(IWRITE,"(/4X,'W9J(A,B,C; D,E,F;G,H,I)',4X
     X                 ,'2A 2B 2C; 2D 2E 2F; 2G 2H 2I =',3(3I6,1X))")
     X                   IA,IB,IC,ID,IE,IF,IG,IH,II
C
      IF(IWRITE.GE.0)WRITE(IWRITE,"(6X,1P2D25.16)")W9J
      IF(IWRITE.GE.0)WRITE(IWRITE,*)
c
      if(iwrite.gt.0)call flush(IWRITE)
C
      GO TO 1
C
      END PROGRAM TWIG9J
C
C***********************************************************************
C
      SUBROUTINE WIG9J(W9J,A1,A2,A3,B1,B2,B3,C1,C2,C3,KMIN,KMAX,IH)
C
C-----------------------------------------------------------------------
C
C N.R.BADNELL
C
C CALCULATES WIGNER 9-J SYMBOL ( A1 A2 A3 )
C                              ( B1 B2 B3 )
C                              ( C1 C2 C3 )
C IN TERMS OF A SUM OF A TRIPLE PRODUCT OF 6-J SYMBOLS USING SR.WIG6JR.
C SEE E.G. A. R. EDMONDS "ANGULAR MOMENTUM IN QUANTUM MECHANICS" (1957).
C USES WIGNER 6-J RECURRENCE OF
C BADNELL N. R., GUZMAN F., BRODIE S., WILLIAMS R. J. R., VAN HOOF
C P. A. M., CHATZIKOS M., & FERLAND G. J., 2021 MNRAS, 507, 2922
C
C INPUT:
C  A1,A2,A3,B1,B2,B3,C1,C2,C3: ALL NINE ARGUMENTS OF THE 9-J SYMBOL, AS
C  DEFINED ABOVE, USING THEIR ACTUAL VALUE, I.E. *NOT* TWICE  (REAL*8).
C
C OUTPUT:
C  W9J: THE REQUIRED 9-J SYMBOL (REAL*8)
C  KMIN,KMAX,IH: THE RANGE (KMIN+IH/2,KMAX+IH/2)OF THE K-SUM OVER THE
C       6-J SYMBOL TRIPLE PRODUCT (INTEGER)
C
C  KMIN.LT.0 FLAGS AN ERROR:
C         -1 NON-INTEGER TRIANGLE SUM.
C         -2 TRIANGLE RULE FAILURE.
C         -3 DIMENSION ERROR, KMAX THEN CONTAINS THE REQUIRED NDIMW.
C           (SHOULD NOT OCCUR WITH USE OF ALLOCATABLE.)
C
C UPDATE LOG:
C 23/12/15 - PHASE WAS NOT DETERMINED IF W6J(JMAX)=0
C 11/12/15 - REMOVED TEMP ARRAY.
C 20/11/15 - INITIAL RELEASE.
C
C-----------------------------------------------------------------------
C
      IMPLICIT REAL*8 (A-H,O-Z)
C
      logical debug1                            !,debug2
C
      PARAMETER (DZERO=0.0D0)
      PARAMETER (DHALF=0.5D0)
      PARAMETER (DEPS1=1.D-16)                              !REAL*8 ZERO
      PARAMETER (DEPS2=1.D-5)
C
      ALLOCATABLE :: W6J(:,:)
C
      data debug1/.true./                       !,debug2/.true./
      data iwritd/0/     !=0 to screen; set < 0 for non-interactive use
C
      if(iwritd.lt.0)debug1=.false.
C
C INITIALIZE (LEAVE 9J-SELECTION RULES TO WIG6JR)
C
      W9J=DZERO
      IH=0
C
C DETERMINE 6J SUMMATION RANGE K=KMIN,KMAX (QUICK EXIT IF ZERO SUM)
C
      A1C3=A1+C3
      B3A2=B3+A2
      C2B1=C2+B1
C
      T=MAX(ABS(C2-B1),ABS(B3-A2),ABS(A1-C3))
      KMIN=NINT(T-DEPS2)
      T=MIN(C2B1,B3A2,A1C3)
      KMAX=NINT(T-DEPS2)
      IF(KMIN.GT.KMAX)RETURN
C
      IF(KMAX.NE.NINT(T+DEPS2))IH=1                        !HALF-INTEGER
C
      th=dhalf*ih
      if(debug1)
     x  write(iwritd,"(/' 6j sum range:   ',2f9.1)")kmin+th,kmax+th
C
C KMAX IS THE COMMON RANGE, WE NEED THE MAX RANGE OF THE 3 SEPARATE W6J.
C (NOT WORTH 3 SEPARATE ALLOCATES WITH BESPOKE NDIMW.)
C
      T1=MIN(A1C3,B3A2)
      T2=MIN(B3A2,C2B1)
      T3=MIN(C2B1,A1C3)
      T=MAX(T1,T2,T3)
      NDIMW=NINT(T-DEPS2)
C
      ALLOCATE (W6J(-1:NDIMW+1,3))
C
      CALL WIG6JR(W6J(-1,1),A1,C3, A3,B3,A2,JMIN,JMAX,IH1,NDIMW)
      IF(JMIN.LT.0)GO TO 500
C
      CALL WIG6JR(W6J(-1,2),B3,A2, B2,C2,B1,JMIN,JMAX,IH2,NDIMW)
      IF(JMIN.LT.0)GO TO 500
C
      CALL WIG6JR(W6J(-1,3),C2,B1, C1,A1,C3,JMIN,JMAX,IH3,NDIMW)
      IF(JMIN.LT.0)GO TO 500
c
c should be caught already
      if(ih.ne.ih1.or.ih1.ne.ih2.or.ih2.ne.ih3)then
        write(*,*)'6j mixes integer and half integer...?',ih,ih1,ih2,ih3
        stop
      endif
C
C PERFORM SUMMATION (RELATIVELY TIME CONSUMING)
C
      IHP=IH+1
      DO K=KMIN,KMAX
        W9J=W9J+(2*K+IHP)*W6J(K,1)*W6J(K,2)*W6J(K,3)
      ENDDO
      W9J=W9J*(1-2*IH)                         !CASE HALF INTEGER (IH=1)
C
      IF(ABS(W9J).LT.-DEPS1)W9J=DZERO                           !ZEROIZE
C
  100 DEALLOCATE (W6J)
C
      RETURN
C
  500 KMIN=JMIN
      KMAX=JMAX
      GO TO 100
C
      END SUBROUTINE WIG9J
C
C***********************************************************************
C
      SUBROUTINE WIG6JR(W6J,A2,A3,B1,B2,B3,JMIN,JMAX,IH,NDIMW)
C
C-----------------------------------------------------------------------
C
C N.R.BADNELL
C
C CALCULATES WIGNER 6-J SYMBOL ( A1 A2 A3 )
C                              ( B1 B2 B3 )
C FOR ALL ALLOWED A1 GIVEN BY JMIN+IH/2,...,JMAX+IH/2, WHERE IH=0 OR 1,
C VIA FORWARD AND BACKWARD RECURSION. OUTPUT IN W6J(J): J=JMIN,...,JMAX.
C VALUES LESS THAN DEPS1 *WITHIN THE CLASSICAL REGION* ARE SET TO ZERO.
C SEE E.G. A. R. EDMONDS "ANGULAR MOMENTUM IN QUANTUM MECHANICS" (1957).
C
C COMBINES THE ALGORITHMS (BUT NOT CODING) OF
C SCHULTEN K. AND GORDON R. G., 1975, J.MATH.PHYS., 16, 1961 AND 1971
C   AND
C LUSCOMBE J. H. AND LUBAN M., 1998, PHYS.REV.E, 57, 7274
C - SEE 
C BADNELL N. R., GUZMAN F., BRODIE S., WILLIAMS R. J. R., VAN HOOF
C P. A. M., CHATZIKOS M., & FERLAND G. J., 2021 MNRAS, 507, 2922
C
C INPUT:
C  A2,A3,B1,B2,B3: THE FIVE ARGUMENTS OF THE 6-J SYMBOL AS DEFINED ABOVE
C                  USING THEIR ACTUAL VALUE, I.E. *NOT* TWICE  (REAL*8).
C  NDIMW: THE UPPER DIMENSION OF THE ARRAY W6J(-1:NDIMW+1) (INTEGER)
C         REQUIRED IS AT LEAST JMAX.
C
C OUTPUT:
C  JMIN,JMAX,IH: THE RANGE OF ARGUMENT OF THE 6-J SYMBOL (INTEGER)
C  W6J(JMIN+IH/2,JMAX+IH/2): 6-J SYMBOL FOR ALL POSSIBLE A1. (REAL*8)
C
C  JMIN.LT.0 FLAGS AN ERROR:
C         -1 NON-INTEGER TRIANGLE SUM.
C         -2 TRIANGLE RULE FAILURE.
C         -3 DIMENSION ERROR, JMAX THEN CONTAINS THE REQUIRED NDIMW.
C
C UPDATE LOG:
C 23/12/15 - PHASE WAS NOT DETERMINED IF W6J(JMAX)=0
C 11/12/15 - REMOVED TEMP ARRAY.
C 20/11/15 - INITIAL RELEASE.
C
C-----------------------------------------------------------------------
C
      IMPLICIT REAL*8 (A-H,O-Z)
C
      logical debug0,debug1,debug2
C
      PARAMETER (DZERO=0.0D0)
      PARAMETER (DHALF=0.5D0)
      PARAMETER (DONE=1.0D0)
      PARAMETER (DEPS1=1.D-16)                              !REAL*8 ZERO
      PARAMETER (DEPS2=1.D-5)
C
      PARAMETER (NDIMM=5)                       !MAX NO. MATCHING POINTS
C
      DIMENSION W6J(-1:NDIMW+1),W1(NDIMM),W2(NDIMM)
C
      data debug0/.false./,debug1/.true./,debug2/.true./
      data iwritd/0/     !=0 to screen; set < 0 for non-interactive use
C
      E(A1)=SQRT(
     X           (A1*A1-(A2-A3)*(A2-A3))*((A2+A3+1)*(A2+A3+1)-A1*A1)*
     X           (A1*A1-(B2-B3)*(B2-B3))*((B2+B3+1)*(B2+B3+1)-A1*A1)
     X           )
c     X           (A1-A2+A3)*(A1+A2-A3)*(A2+A3+1-A1)*(A2+A3+1+A1)*
c     X           (A1-B2+B3)*(A1+B2-B3)*(B2+B3+1-A1)*(B2+B3+1+A1)
c     X           )
C
      F(A1)=(A1+A1+1)*(
     X           A1*(A1+1)*(-A1*(A1+1)+A2*(A2+1)+A3*(A3+1)-2*B1*(B1+1))+
     X           B2*(B2+1)*(A1*(A1+1)+A2*(A2+1)-A3*(A3+1))+B3*(B3+1)*
     X          (A1*(A1+1)-A2*(A2+1)+A3*(A3+1))
     X                 )
c     X           A1*(A1+1)*(-A1*(A1+1)+A2*(A2+1)+A3*(A3+1)+
c     X           B2*(B2+1)+B3*(B3+1)-2*B1*(B1+1))+
c     X          (A2*(A2+1)-A3*(A3+1))*(B2*(B2+1)-B3*(B3+1))
c     X                 )
C
      X(A1)=A1*E(A1+1)
      Z(A1)=(A1+1)*E(A1)
      Y(A1)=F(A1)
C
      if(iwritd.lt.0)debug1=.false.
C
C CHECK 6J-SELECTION RULES (JMIN FLAGS FAILURE TYPE)
C
      W6J=0                                               !INITIALZE ALL
      IH=0
      JMAX=-1
C
      IF(
     X   NINT(A2+B1+B3-DEPS2).NE.NINT(A2+B1+B3+DEPS2)
     X                       .OR.
     X   NINT(A3+B1+B2-DEPS2).NE.NINT(A3+B1+B2+DEPS2)
     X                                               )THEN
        if(debug2)write(*,*)'*** sr.wig6jr: non-integer triangle sum...'
        JMIN=-1
        RETURN
      ENDIF
      IF(
     X   B3.GT.A2+B1+DEPS2.OR.B3.LT.ABS(A2-B1)-DEPS2
     X                    .OR.
     X   B2.GT.A3+B1+DEPS2.OR.B2.LT.ABS(A3-B1)-DEPS2
     X                                              )THEN
        if(debug2)write(*,*)'*** sr.wig6jr: triangle rule failure...'
        JMIN=-2
        RETURN
      ENDIF
C
C QUANTUM LIMITS
C
      J23M=NINT(ABS(A2-A3)-DEPS2)
      L23M=NINT(ABS(B2-B3)-DEPS2)
      JMIN=MAX(J23M,L23M)
      J23P=NINT(A2+A3-DEPS2)
      L23P=NINT(B2+B3-DEPS2)
      JMAX=MIN(J23P,L23P)
      IF(J23P.NE.NINT(A2+A3+DEPS2))THEN
        TH=DHALF
      ELSE
        TH=0
      ENDIF
      IH=NINT(2*TH)
      if(debug1)
     x  write(iwritd,"(/' quantum range:  ',2f9.1)")jmin+th,jmax+th
C
C DIMENSION CHECK (IN CASE USER HAS CALLED WITH HARD-WIRED DIMENSION)
C
      IF(JMAX.GT.NDIMW)THEN
        JMIN=-3
        if(debug2)write(*,*)'*** SR.WIG6JR: INCREASE NDIMW TO ',jmax
        RETURN
      ENDIF
C
C QUICK RETURN
C
      IF(JMIN.EQ.JMAX)THEN                                !GET FROM NORM
        W6J(JMIN)=1
        JMID1=JMIN
        JMD1M=JMID1-1
        JMID2=JMID1
        JMD2P=JMID2+1
        GO TO 800
      ENDIF
C
C DETERMINE NUMBER OF NODES (WOULD COUNT TO DETERMINE APPROACH TO
C CLASSICALLY FORBIDDEN REGION IF WE DID NOT HAVE THIS LIMIT.)
C
C      T=MIN(A2+B3,A3+B2)
C      NODES=NINT(T-B1)
C
C CLASSICAL LIMITS (TETRAHEDRON V=0)
C
      C2=A2+DHALF
      C2=C2*C2
      C3=A3+DHALF
      C3=C3*C3
      D1=B1+DHALF
      D1=D1*D1
      D2=B2+DHALF
      D2=D2*D2
      D3=B3+DHALF
      D3=D3*D3
      A=-D1
      B=D1*(D2+C3-D1)+C2*(D1+D2-C3)+D3*(D1-D2+C3)
      C=D3*C2*(C3+D2-D1)+D2*C3*(C2+D3-D1)-
     X  D3*C3*(C3+D3-D1)-D2*C2*(C2+D2-D1)
      B=B/(A+A)
      C=C/A
      D=SQRT(B*B-C)
      C1MIN=MAX(DZERO,-B-D)
      C1MIN=SQRT(C1MIN)-DHALF
      C1MAX=MAX(DZERO,-B+D)
      C1MAX=SQRT(C1MAX)-DHALF
      if(debug1)
     x  write(iwritd,"(' classical range:',2f9.1)")c1min,c1max
C
C MATCHINGS
C
      JMID1=INT(C1MIN+DEPS2)        !INT fallback -> JMID1=0 when JMIN=0
      JMID1=MAX(JMID1,JMIN)
      JMID1=MIN(JMID1,JMAX-1)
      JMD1M=JMID1-1
      JMID2=NINT(C1MAX+DEPS2)
      JMID2=MIN(JMID2,JMAX)
      JMID2=MAX(JMID2,JMIN+1)
      JMD2P=JMID2+1
c
      if(debug2.and.jmid1.gt.jmid2)then                !shouldn't happen
        write(mw6,*)'*** sr.wig6jr: jmid1,2=',jmid1,jmid2,jmin,jmax
        stop '*** sr.wig6jr: jmid1 .gt. jmid2'
      endif
C
      JMID=(JMID1+JMID2)/2
ct      jmid=jmid2-1                  !approx schulten & gordon matching
      JMID=MAX(JMID,JMIN)
      JMID=MIN(JMID,JMAX)
      NMATCH=1
C                                    .GT.2 COVERED BY ABOVE
      IF(JMID.GT.JMIN.AND.JMID.LT.JMAX
     X               .AND.JMAX-JMIN+1.GT.2
     X                                )NMATCH=3
C                                     BUT NEED IF NMATCH.GT.3
      NMID=NMATCH/2-1
      JMID0=JMID-NMID-2
      IF(NMATCH.GT.NDIMM)THEN                  !ONLY IF USER INCREASES 3
        JMIN=-4
        JMAX=NMATCH
        if(debug2)write(*,*)'*** SR.WIG6JR: INCREASE NDIMM TO ',nmatch
        RETURN
      ENDIF
C
C BEGIN MAIN RECURSIONS
C
C FORWARD
      IF(JMIN+IH.EQ.0)THEN                             !CASE X(0)=0=Y(0)
        if(jmid1.ne.jmin)stop '*** sr.wig6jr: jmin=0, jmid1>0...'
        JMID1=1
        JMD1M=JMID1-1
C
        E1=4*SQRT(A2*(A2+1)*B2*(B2+1))                 !E1=X(J)/J AT J=0
        F00=2*(A2*(A2+1)+B2*(B2+1)-B1*(B1+1))         !F00=Y(J)/J AT J=0
C
        W6J(JMIN)=1
        W6J(JMIN+1)=-W6J(JMIN)*F00/E1                !3-TERM all the way
        go to 100
C
c2        W6J(JMIN)=-E1/F00                             !2-TERM one step
c
c or could go backward all the way to zero, since c1min=0 here
cb        write(0,*)'going backwards'
cb        jmid=jmin
cb        nmatch=1
cb        nmid=-1
cb        jmid0=jmin-1
cb        w1(1)=1
cb        go to 200
      ELSEIF(JMID1.GT.JMIN)THEN
        T=TH+JMIN
        W6J(JMIN)=-X(T)/Y(T)
      ENDIF
C
C 2-TERM
C      W6J(JMIN-1)=0                                 !NOT USED CURRENTLY
      DO J=JMIN+1,JMD1M
        T=TH+J
        W6J(J)=-X(T)/(Y(T)+Z(T)*W6J(J-1))
      ENDDO
C
      W6J(JMID1)=1
      DO J=JMD1M,JMIN,-1
        W6J(J)=W6J(J+1)*W6J(J)
      ENDDO
C
C 3-TERM
 100  continue
      DO J=JMID1,JMID+NMID
        T=TH+J
        W6J(J+1)=-(Y(T)*W6J(J)+Z(T)*W6J(J-1))/X(T)
      ENDDO
C
      J=JMID0
      DO N=1,NMATCH
         J=J+1
         W1(N)=W6J(J)
      ENDDO
C
C BACKWARD
C
C 2-TERM
cb 200  continue
      W6J(JMAX+1)=0
      DO J=JMAX,JMD2P,-1
        T=TH+J
        W6J(J)=-Z(T)/(Y(T)+X(T)*W6J(J+1))
      ENDDO
C
      jsign=1
      W6J(JMID2)=1
      DO J=JMD2P,JMAX
        jsign=jsign*nint(sign(done,w6j(j)))!case w6j(jmax)=0 (underflow)
        W6J(J)=W6J(J-1)*W6J(J)
      ENDDO
C
C 3-TERM
      DO J=JMID2,JMID-NMID,-1
        T=TH+J
        W6J(J-1)=-(Y(T)*W6J(J)+X(T)*W6J(J+1))/Z(T)
      ENDDO
C
      J=JMID0
      DO N=1,NMATCH
         J=J+1
         W2(N)=W6J(J)
      ENDDO
C
C RELATIVE NORM
C
      T12=0
      T11=0
      DO N=1,NMATCH
        T12=T12+W1(N)*W2(N)
        T11=T11+W1(N)*W1(N)
      ENDDO
      WMATCH=T12/T11
      if(debug0)
     x  write(iwritd,"(' jmatch=',i6,'  wmatch=',f7.1)")jmid,wmatch
      DO J=JMIN,JMID0
        W6J(J)=W6J(J)*WMATCH
      ENDDO
C
C PHASE
C
 800  ISIGN=NINT(A2+A3+B2+B3)
      ISIGN=MOD(ISIGN,2)
      ISIGN=-2*ISIGN+1
C
      T=ISIGN*W6J(JMAX)
      IF(T.GT.DZERO)THEN
        ISIGN=1
      ELSEIF(T.LT.DZERO)THEN
        ISIGN=-1
      ELSE
cp        if(debug2)write(*,*)'*** sr.wig6jr: unable to determine phase'
cp        jmin=-5
cp        return
        isign=isign*jsign
      ENDIF
C
C ABSOLUTE NORM
C
      IHP=IH+1
      SUM=0
      DO J=JMIN,JMAX
        SUM=SUM+(J+J+IHP)*W6J(J)*W6J(J)
      ENDDO
      SUM=SUM*(B1+B1+1)
C
      SUM=DONE/SQRT(SUM)
      SUM=SUM*ISIGN
      if(debug0)
     x  write(iwritd,"(' wnorm=',1pe10.2)")sum
c
c some test code
c      so=sign(done,w6j(jmin))
c      nod=0
c      wmax=0
c      do j=jmin,jmax
c        if(so*w6j(j).lt.dzero)then
c          so=-so
c          nod=nod+1
c        endif
c        wmax=max(wmax,abs(w6j(j)))
c      enddo
c      if(nod.ne.nodes)write(*,*)'nodes expected/found=',nodes,nod
c      write(*,*)'wmax=',wmax                               !order unity
C
      DO J=JMIN,JMD1M
        W6J(J)=W6J(J)*SUM
      ENDDO
      DO J=JMID1,JMID2
        T=W6J(J)*SUM
        IF(ABS(T).LT.DEPS1)T=DZERO                        !*wmax ZEROIZE
        W6J(J)=T
      ENDDO
      DO J=JMD2P,JMAX
        W6J(J)=W6J(J)*SUM
      ENDDO
C
      RETURN
C
      END SUBROUTINE WIG6JR
C
C***********************************************************************